Lately I’ve been working my way through Mastering Bitcoin, implementing as many of the examples in the book in Elixir as I can.
I’ve been amazed at how well Elixir has fared with implementing the algorithms involved in working with Bitcoin keys and addresses. Elixir ships with all the tools required to generate a cryptographically secure private key and transform it into a public address string.
Let’s walk through the process step by step and build our our own Elixir module to generate private keys and public addresses.
A Bitcoin private key is really just a random two hundred fifty six bit number. As the name implies, this number is intended to be kept private.
From each private key, a public-facing Bitcoin address can be generated. Bitcoin can be sent to this public address by anyone in the world. However, only the keeper of the private key can produce a signature that allows them to access the Bitcoin stored there.
Let’s use Elixir to generate a cryptographically secure private key and then generate its most basic corresponding public address so we can receive some Bitcoin!
As I mentioned earlier, a Bitcoin private key is really just a random two hundred and fifty six bit number. In other words, a private key can be any number between 0 and 2^256.
However, not all random numbers are created equally. We need to be sure that we’re generating our random number from a cryptographically secure source of entropy. Thankfully, Elixir exposes Erlang’s :crypto.strong_rand_bytes/1 function which lets us easily generate a list of truly random bytes.
Let’s use :crypto.strong_rand_bytes/1 as the basis for our private key generator. We’ll start by creating a new PrivateKey module and a generate/0 function that takes no arguments:
defmodule PrivateKey do
def generate
end
Inside our generate/0 function, we’ll request 32 random bytes (or 256 bits) from :crypto.strong_rand_bytes/1:
def generate do
:crypto.strong_rand_bytes(32)
end
This gives us a random set of 32 bytes that, when viewed as an unsigned integer, ranges between 0 and 2^256 - 1.
Unfortunately, we’re not quite done.
To ensure that our private key is difficult to guess, the Standards for Efficient Cryptography Group recommends that we pick a private key between the number 1 and a number slightly smaller than 1.158e77:
We can add this validation check fairly easily by adding the SECG-provided upper bound as an attribute to our PrivateKey module:
@n :binary.decode_unsigned(<<
0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF,
0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFE,
0xBA, 0xAE, 0xDC, 0xE6, 0xAF, 0x48, 0xA0, 0x3B,
0xBF, 0xD2, 0x5E, 0x8C, 0xD0, 0x36, 0x41, 0x41
>>)
Next, we’ll add a valid?/1 function to our module that returns true if the provided secret key falls within this range, and false if it does not:
defp valid?(key) when key > 1 and key < @n, do: true
defp valid?(_), do: false
Before we pass our private key into our valid?/1 function, we’ll need to convert it from a thirty two byte binary into an unsigned integer. Let’s add a third valid?/1 function head that does just that:
defp valid?(key) when is_binary(key) do
key
|> :binary.decode_unsigned
|> valid?
end
We’ll finish off our validation by passing our generated private key into our new valid?/1 function. If the key is valid, we’ll return it. Otherwise, we’ll generate a new private key and try again:
def generate do
private_key = :crypto.strong_rand_bytes(32)
case valid?(private_key) do
true -> private_key
false -> generate
end
end
Now we can call PrivateKey.generate to generate a new Bitcoin private key!
The most basic process for turning a Bitcoin private key into a sharable public address involves three basic steps. The first step is to transform our private key into a public key with the help of elliptic curve cryptography.
We’ll start by adding a new to_public_key/1 function to our PrivateKey module:
def to_public_key(private_key)
In our to_public_key/1 function, we’ll use Erlang’s :crypto.generate_key function to sign our private_key using an elliptic curve. We’ll specifically use the :secp256k1 curve:
:crypto.generate_key(:ecdh, :crypto.ec_curve(:secp256k1), private_key)
We’re using the elliptic curve key generation as a trapdoor function to ensure our private key’s secrecy. It’s easy for us to generate our public key from our private key, but reversing the computation and generating our private key from our public key is nearly impossible.
The :crypto.generate_key function returns a two-element tuple. The first element in this tuple is our Bitcoin public key. We’ll pull it out using Elixir’s elem/1 function:
:crypto.generate_key(:ecdh, :crypto.ec_curve(:secp256k1), private_key)
|> elem(0)
The returned value is a sixty five byte binary representing our public key!
Once we have our public key in memory, our next step in transforming it into a public address is to hash it. This gives us what’s called the “public hash” of our public key.
Let’s make a new function, to_public_hash/1 that takes our private_key as an argument:
def to_public_hash(private_key)
We’ll start the hashing process by turning our private_key into a public key with a call to to_public_key:
private_key
|> to_public_key
Next, we pipe our public key through two hashing functions: SHA-256, followed by RIPEMD-160:
private_key
|> to_public_key
|> hash(:sha256)
|> hash(:ripemd160)
Bitcoin uses the RIPEMD-160 hashing algorithm because it produces a short hash. The intermediate SHA-256 hashing is used to prevent insecurities through unexpected interactions between our elliptic curve signing algorithm and the RIPEMD algorithm.
In this example, hash/1 is a helper function that wraps Erlang’s :crypto.hash.
defp hash(data, algorithm), do: :crypto.hash(algorithm, data)
Flipping the arguments to :crypto.hash in this way lets us easily pipe our data through the hash/1 helper.
Lastly, we can convert our public hash into a full-fledged Bitcoin address by Base58Check encoding the hash with a version byte corresponding to the network where we’re using the address.
Let’s add a to_public_address/2 function to our PrivateKey module:
def to_public_address(private_key, version \\ <<0x00>>)
The to_public_address/2 function takes a private_key and a version byte as its arguments. The version defaults to <<0x00>>, indicating that this address will be used on the live Bitcoin network.
To create a Bitcoin address, we start by converting our private_key into a public hash with a call to to_public_hash/1:
private_key
|> to_public_hash
All that’s left to do is Base58Check encode the resulting hash with the provided version byte:
private_key
|> to_public_hash
|> Base58Check.encode(version)
After laying the groundwork, the final pieces of the puzzle effortlessly fall into place.
Now that we can generate cryptographically secure private keys and transform them into publishable public addresses, we’re in business.
Literally!
Let’s generate a new private key, transform it into its corresponding public address, and try out on the Bitcoin testnet. We’ll start by generating our private key:
private_key = PrivateKey.generate
This gives us a thirty two byte binary. If we wanted, we could Base58Check encode this with a testnet version byte of 0xEF. This is known as the “Wallet Import Format”, or WIF, of our Bitcoin private key:
Base58Check.encode(private_key, <<0xEF>>)
As its name suggests, converting our private key into a WIF allows us to easily import it into most Bitcoin wallet software:
Next, let’s convert our private key into a testnet public address using a version byte of 0x6F:
PrivateKey.to_public_address(private_key, <<0x6F>>)
Now that we have our public address, let’s find a testnet faucet and send a few tBTC to our newly generated address! After initiating the transaction with our faucet, we should see our Bitcoin arrive at our address on either a blockchain explorer, or within our wallet software.
Victory!
Elixir, thanks to its Erlang heritage, ships with a wealth of tools that make this kind of hashing, signing, and byte mashing a walk in the park.
I encourage you to check our the PrivateKey module on Github to get a better feel for the simplicity of the code we wrote today. Overall, I’m very happy with the result.
If you enjoyed this article, I highly recommend you check out the Mastering Bitcoin book. If you really enjoyed this article, feel free to send a few Bitcoin to this address I generated using our new PrivateKey module:
1HKz4XU7ENT46ztEzsT83jRezyiDjvnBV8
Stay tuned for more Bitcoin-related content as I work my way through Mastering Bitcoin!